@echo off
rem *****************************
rem * TELEMAC-MASCARET settings *
rem *****************************
rem Path to TELEMAC root dir
for %%a in ("%~dp0.") do set HOMETEL=%%~dpa
set HOMETEL=%HOMETEL:~0,-1%
rem Path to dependencies
set EXTERNAL=%HOMETEL%\external
rem Path to this file
set SOURCEFILE=%~dp0%~n0%~x0
rem Configuration file
set SYSTELCFG=%~dp0systel.cfg
rem Name of the configuration to use
set USETELCFG=gnu.static

rem Activate TELEMAC Python environment and set it as the default
rem one to launch Python scripts from the command line
call %EXTERNAL%\python\Scripts\activate.bat

rem Add Mingw to PATH if it is found
call :find_mingw

rem Add TELEMAC binaries directory to PATH
set PATH=%HOMETEL%\builds\%USETELCFG%\lib;%PATH%
rem Add TELEMAC Python scripts to PATH and to Python environment
set PATH=%HOMETEL%\scripts\python3;%PATH%
set PYTHONPATH=%HOMETEL%\scripts\python3;%PYTHONPATH%
set PYTHONPATH=%HOMETEL%\builds\%USETELCFG%\wrap_api\lib;%PYTHONPATH%

rem External libraries versions
rem HDF5
set HDF5HOME=%EXTERNAL%\hdf5-1.10.9
set PATH=%HDF5HOME%\bin;%PATH%
rem MED
set MEDHOME=%EXTERNAL%\med-4.1.1
set PATH=%MEDHOME%\bin;%PATH%
rem METIS
set METISHOME=%EXTERNAL%\metis-5.1.0
set PATH=%METISHOME%\bin;%PATH%
rem MSPMPI
set MPIHOME=%EXTERNAL%\msmpi-10.1.2
set PATH=%MPIHOME%\bin;%PATH%
rem OPENBLAS, SCALAPACK and MUMPS
set OPENBLASHOME=%EXTERNAL%\openblas-0.3.21
set SCALAPACKHOME=%EXTERNAL%\scalapack-2.1.0
set MUMPSHOME=%EXTERNAL%\mumps-5.2.1
rem AED
set AEDHOME=%EXTERNAL%\libaed2-1.2.0
rem GOTM
set GOTMHOME=%EXTERNAL%\gotm-2019-06-14-opentelemac
set PATH=%GOTMHOME%\bin;%PATH%

exit /b 0

:find_mingw
rem Try to find Mingw in current user PATH
for /f "delims=" %%a in ('"where mingw32-make 2>nul"') do set MINGW_PATH=%%a
rem If not found, add usual Mingw location to PATH
if not defined MINGW_PATH set PATH=C:\mingw64\bin;%PATH%
for /f "delims=" %%a in ('"where mingw32-make 2>nul"') do set MINGW_PATH=%%a
if not defined MINGW_PATH (
  echo Warning: Mingw not found. Please ensure that Mingw bin folder is in your PATH or
  echo you will not be able to compile TELEMAC-MASCARET or compile user Fortran code.
)

exit /b 0